IMPRIMER ETIQUETTES

4D - Documentation   Français   English   German   Español   Japanese   4D v11 SQL, Commandes par thèmes   4D v11 SQL, Liste alphabétique des commandes   4D v11 SQL, Constantes par thèmes   Retour   Précédent   Suivant

version 2004 (Modifiée)


IMPRIMER ETIQUETTES ({table}{; étiqFichier{; * | >}})

ParamètreTypeDescription
tableTableTable à imprimer ou
Table par défaut si ce paramètre est omis
étiqFichierAlphaNom de fichier d'étiquettes sur disque
* | >* | >* pour supprimer les boîtes de dialogue
d'impression ou
> pour ne pas réinitialiser les paramètres
d'impression

Description

IMPRIMER ETIQUETTES vous permet d'imprimer des étiquettes à partir des données de la sélection de table.

Si vous ne spécifiez pas le paramètre étiqFichier, IMPRIMER ETIQUETTES imprime la sélection courante de table sous forme d'étiquettes, en utilisant le formulaire sortie courant du process. Vous ne pouvez pas imprimer de sous-formulaires lorsque vous utilisez cette commande. Pour plus d'informations sur la création d'étiquettes à l'aide de formulaires, reportez-vous au manuel Mode Développement de 4D.

Si vous spécifiez le paramètre étiqFichier, IMPRIMER ETIQUETTES vous permet d'imprimer un document d'étiquettes existant stocké sur disque ou d'ouvrir l'Assistant de création d'étiquettes (affiché ci-dessous). Pour plus d'informations sur ce point, reportez-vous à l'exemple plus bas.

Par défaut, IMPRIMER ETIQUETTES affiche les boîtes de dialogue d'impression. Si l'utilisateur annule une des deux boîtes de dialogue, l'exécution de la commande est stoppée et l'état n'est pas imprimé.

Vous pouvez supprimer leur affichage en utilisant soit le paramètre optionnel astérisque (*), soit le paramètre optionnel "supérieur à" (>).

Le paramètre * provoque une impression avec les paramètres d'impression courants.

Le paramètre > provoque en outre l'impression sans réinitialisation des paramètres d'impression. Ce paramètre est utile lorsque vous souhaitez exécuter successivement plusieurs appels à IMPRIMER ETIQUETTES (par exemple à l'intérieur d'une boucle) tout en conservant des paramètres d'impression personnalisés préalablement définis.

Il est à noter que ces paramètres n'ont pas d'effet si l'assistant de création d'étiquettes est utilisé.

Si l'assistant de création d'étiquettes n'est pas utilisé, la variable système OK est mise à 1 si toutes les étiquettes ont été imprimées ; sinon, elle prend la valeur 0 (zéro) (par exemple si l'utilisateur a cliqué sur le bouton Annuler dans les boîtes de dialogue d'impression).

Si vous spécifiez le paramètre étiqFichier, les étiquettes sont imprimées avec les paramétrages définis dans étiqFichier. Si étiqFichier est une chaîne vide (""), IMPRIMER ETIQUETTES affiche une boîte de dialogue standard d'ouverture de documents, permettant à l'utilisateur de sélectionner le fichier d'étiquettes à utiliser. Si étiqFichier est le nom d'un fichier qui n'existe pas ou est invalide (si vous passez, par exemple, Caractere(1) dans étiqFichier), l'assistant de création d'étiquettes s'affiche, permettant à l'utilisateur de créer son propre format d'étiquettes.

Note : Si la table a été déclarée "invisible" en mode Développement, l'assistant de création d'étiquettes n'apparaît pas.

4D Server : Cette commande peut être exécutée sur 4D Server dans le cadre d'une procédure stockée. Dans ce contexte :

Veillez à ce qu'aucune boîte de dialogue n'apparaisse sur le poste serveur (sauf besoin spécifique). Pour cela, il est nécessaire d'appeler la commande avec le paramètre * ou >.

La syntaxe faisant apparaître l'éditeur d'étiquettes ne fonctionne pas avec 4D Server, dans ce cas, la variable système OK prend la valeur 0.

En cas de problème sur l'imprimante (plus de papier, imprimante déconnectée, etc.), aucun message d'erreur n'est généré.

Exemples

(1) L'exemple suivant imprime des étiquettes à l'aide du formulaire de sortie de la table. L'exemple s'appuie sur deux méthodes. La première est une méthode projet qui désigne le formulaire sortie à utiliser puis imprime les étiquettes :

   TOUT SELECTIONNER([Adresses]) ` Sélection de tous les enregistrements 
   FORMULAIRE SORTIE ([Adresses]; "ImprimEtiq")` Sélection du formulaire sortie 
   IMPRIMER ETIQUETTES([Adresses]) ` Impression des étiquettes 
   FORMULAIRE SORTIE ([Adresses];"Sortie") ` Rétablissement du formulaire sortie par défaut

La seconde méthode est la méthode du formulaire "ImprimEtiq". Le formulaire contient une variable, nommée vEtiq, contenant les champs concaténés. Si le second champ Adresse (Adr2) est vide, il est enlevé par la méthode (notez que cette opération peut être effectuée automatiquement par l'assistant de création d'étiquettes). La méthode formulaire construit l'étiquette pour chaque enregistrement :

      ` Méthode formulaire [Adresses];"Etiquette sortie"
   Au cas ou
      : (Evenement formulaire=Sur chargement)
         vEtiq:=[Adresses]Nom1+" "+[Adresses]Nom2+Caractere(13)+[Adresses]Adr1+Caractere(13) 
         Si ([Adresses]Adr2 # "") 
               vEtiq:=vEtiq +[Adresses]Adr2+Caractere(13) 
         Fin de si 
         vEtiq:=vEtiq+[Adresses]Ville+", "+[Adresses]Département+" "+[Adresses]Code Postal
   Fin de cas

(2) L'exemple suivant permet à l'utilisateur d'effectuer une recherche sur la table [Employés], et d'imprimer automatiquement les étiquettes "Mes Etiquettes" :

   CHERCHER ([Employés])
   Si (OK=1)
      IMPRIMER ETIQUETTES ([Employés];"Mes Etiquettes";*)
   Fin de si

(3) L'exemple suivant permet à l'utilisateur d'effectuer une recherche sur la table [Employés], puis de choisir les étiquettes qui doivent être imprimées :

   CHERCHER ([Employés])
   Si (OK=1)
      IMPRIMER ETIQUETTES ([Employés];"")
   Fin de si

(4) L'exemple suivant permet à l'utilisateur d'effectuer une recherche sur la table [Employés], puis affiche l'assistant de création d'étiquettes afin que l'utilisateur puisse concevoir, sauvegarder, charger et imprimer tout type d'étiquettes :

   CHERCHER ([Employés])
   Si (OK=1)
      IMPRIMER ETIQUETTES ([Employés];Caractere(1))
   Fin de si

Référence

IMPRIMER SELECTION, QR ETAT.


4D - Documentation   Français   English   German   Español   Japanese   4D v11 SQL, Commandes par thèmes   4D v11 SQL, Liste alphabétique des commandes   4D v11 SQL, Constantes par thèmes   Retour   Précédent   Suivant