Chercher dans tableau

4D - Documentation   Français   English   German   Español   Japanese   4D v11 SQL, Commandes par thèmes   4D v11 SQL, Liste alphabétique des commandes   4D v11 SQL, Constantes par thèmes   Retour   Précédent   Suivant

version 5


Chercher dans tableau (tableau; valeur{; début}) Numérique

ParamètreTypeDescription
tableauTableauTableau dans lequel effectuer la recherche
valeurExpressionValeur de même type à rechercher dans le tableau
débutNumériqueElément à partir duquel commencer la recherche
RésultatNumériqueNuméro du premier élément trouvé
correspondant à valeur

Description

Chercher dans tableau retourne le numéro du premier élément de tableau qui correspond à valeur.

Chercher dans tableau peut être utilisé avec des tableaux de type Texte, Alpha, Numérique, Date, Pointeur et Booléen. Les paramètres tableau et valeur doivent être du même type.

Si aucun élément n'est trouvé, Chercher dans tableau renvoie –1.

Si début est spécifié, Chercher dans tableau commence la recherche à l'élément spécifié par début. Si début n'est pas spécifié, Chercher dans tableau commence la recherche à l'élément 1.

Exemples

(1) La méthode projet suivante efface tous les éléments vides du tableau alpha ou texte passé en paramètre :

      ` Méthode projet NETTOYER TABLEAU
      ` NETTOYER TABLEAU ( Pointeur )
      ` NETTOYER TABLEAU ( -> Tableau Texte ou Alpha )

   C_POINTEUR ($1)
   Repeter
      $vlElem:=Chercher dans tableau ($1->;"")
      Si ($vlElem>0)
         SUPPRIMER DANS TABLEAU($1->;$vlElem)
      Fin de si
   Jusque ($vlElem<0)

Une fois que cette méthode projet est implémentée dans votre base, vous pouvez écrire, par exemple :

   TABLEAU TEXTE (TabValeurs;...)
      ` ...
      ` Utiliser le tableau comme vous voulez
      ` ...
      ` Eliminer les éléments chaînes vides
   NETTOYER TABLEAU (->TabValeurs)

(2) La méthode projet suivante sélectionne le premier élément d'un tableau dont le pointeur passé comme premier paramètre correspond à la valeur de la variable ou du champ dont le pointeur est passé en second paramètre :

      ` Méthode projet SELECTIONNER ELEMENT
      ` SELECTIONNER ELEMENT ( Pointeur ; Pointeur)
      ` SELECTIONNER ELEMENT ( -> Tableau Texte ou Alpha ; -> Champ ou variable de type Texte ou Alpha )

   $1->:=Chercher dans tableau ($1->;$2->)
   Si ($1->=-1)
      $1->:=0 ` Si aucun élément n'est trouvé, fixer le tableau à aucun élément sélectionné
   Fin de si

Une fois que cette méthode projet est implémentée dans la base, vous pouvez écrire, par exemple :

      ` Méthode objet du pop-up menu TabTitres
   Au cas ou
      : (Evenement formulaire=Sur chargement)
         SELECTIONNER ELEMENT (->TabTitres;->[Personnes]Titre)
   Fin de cas

Référence

INSERER DANS TABLEAU, SUPPRIMER DANS TABLEAU, Taille tableau.


4D - Documentation   Français   English   German   Español   Japanese   4D v11 SQL, Commandes par thèmes   4D v11 SQL, Liste alphabétique des commandes   4D v11 SQL, Constantes par thèmes   Retour   Précédent   Suivant