PV FIXER PROPRIETE STYLE

4D - Documentation   Français   English   German   4D View, Commandes par thèmes   4D View, Liste des commandes   4D View, Constantes par thèmes   Retour   Précédent   Suivant

version 6.8


PV FIXER PROPRIETE STYLE (zone; style; propriété; valeur)

ParamètreTypeDescription
zoneEntier longZone 4D View
styleEntier longNuméro de la feuille de style
propriétéEntier longNuméro de la propriété
valeurEntier longValeur de la propriété

Description

La commande PV FIXER PROPRIETE STYLE fixe la valeur de propriété pour la feuille de style dont le numéro est style.

Utilisez les constantes du thème PV Propriétés style pour définir le paramètre propriété.

Utilisez les constantes du thème PV Valeurs style pour définir le paramètre valeur. Le choix de la constante à affecter au paramètre valeur dépend de la propriété choisie.

Ces constantes sont détaillées dans la description de la commande PV FIXER PROPRIETE CELLULE. Les informations fournies pour chaque paire propriété/valeur s'appliquent de manière identique aux feuilles de style.

Si vous souhaitez définir les propriétés des feuilles de styles par défaut, passez une constante du thème PV Style valeurs spéciales dans le paramètre style :

pv style cellules : feuille de style par défaut nommée "Cellules", appliquée aux cellules.

pv style entêtes col lig : feuille de style par défaut nommée "En-têtes de lignes/colonnes", appliquée aux en-têtes de colonnes et de lignes.

pv style entête pied page : feuille de style par défaut nommée "En-tête et pied de page", appliquée à l'en-tête et au pied de page lors de l'impression.

Note : Ces feuilles de styles sont accessibles via la commande Feuilles de style du menu Format de 4D View.

Exemple

Cette méthode permet de définir les propriétés d'un nouveau style. Dans cet exemple, nous allons définir une valeur pour chacune des trois propriétés de styles à personnaliser :

la propriété "alignement horizontal" prendra la valeur "à gauche",

la propriété "alignement vertical" prendra la valeur "centré",

la propriété "rotation" prendra la valeur "90 degrés".

   TABLEAU ENTIER LONG($TabPropriétés;3)  `Tableau de propriétés de la feuille de style
   TABLEAU ENTIER LONG($TabValeurs;3)  `Valeur de chaque propriété

   C_ALPHA(255;$NomStyle)  `Nom de style à ajouter à la Zone

   TABLEAU ENTIER LONG($TabNumStyles;0)  `Tableau des numéros de styles
   TABLEAU ALPHA(255;$TabNomStyles;0)  `Tableau des noms de styles
   C_ENTIER($Indice)  `Indice de boucle
   C_ENTIER($Position)  `Position du nouveau style dans les tableaux de numéros et de noms

      `Initialisations
   $TabPropriétés{1}:=pv style alignement hor   `Propriétés...
   $TabPropriétés{2}:=pv style alignement vert 
   $TabPropriétés{3}:=pv style rotation 

   $TabValeurs{1}:=pv valeur align hor gauche   `...et valeurs correspondantes
   $TabValeurs{2}:=pv valeur align vert centré 
   $TabValeurs{3}:=pv valeur rotation 90 

   $NomStyle:="Sous-paragraphe"

   PV LIRE LISTE STYLES (Zone;$TabNumStyles;$TabNomStyles)  `Liste des styles disponibles

   Si (Chercher dans tableau($TabNomStyles;$NomStyle)=-1)  `Style $NomStyle absent ?
      $Position:=Taille tableau($TabNomStyles)+1  `Nous allons l'ajouter
      INSERER LIGNES($TabNomStyles;$Position)  `Redimensionnement des tableaux
      INSERER LIGNES($TabNumStyles;$Position)
      $TabNomStyles{$Position}:=$NomStyle  `Affectation du nom du nouveau style
      $TabNumStyles{$Position}:=PV Ajouter style (Zone;$NomStyle)  `Affectation du numéro du nouveau style

      Boucle ($Indice;1;Taille tableau($TabPropriétés))  `Pour toutes les propriétés à définir
         Si (PV Lire propriete style (Zone;$TabNumStyles{$Position};$TabPropriétés{$Indice})#$TabValeurs{$Indice})
            PV FIXER PROPRIETE STYLE (Zone;$TabNumStyles{$Position};$TabPropriétés{$Indice};$TabValeurs{$Indice})
         Fin de si   `Propriété n'ayant pas la valeur souhaitée ?
      Fin de boucle   `Passage en revue du tableau $TabPropriétés des propriétés de la feuille de style

   Sinon 
      ALERTE("Le style '"+$NomStyle+"' est déjà présent pour la zone.")
   Fin de si

Référence

PV Lire propriete style.

Constantes

Thèmes PV Propriétés style et PV Valeurs style.


4D - Documentation   Français   English   German   4D View, Commandes par thèmes   4D View, Liste des commandes   4D View, Constantes par thèmes   Retour   Précédent   Suivant