PV FIXER NOM CELLULE

4D - Documentation   Français   English   German   4D View, Commandes par thèmes   4D View, Liste des commandes   4D View, Constantes par thèmes   Retour   Précédent   Suivant

version 2004.1 (Modifiée)


PV FIXER NOM CELLULE (zone; colonne; ligne; nom{; mode})

ParamètreTypeDescription
zoneEntier longZone 4D View
colonneEntier longNuméro de colonne de la cellule
ligneEntier longNuméro de ligne de la cellule
nomAlphaNom de la cellule
modeEntier long0 ou omis=Ajouter le nom, 1=Remplacer le nom

Description

La commande PV FIXER NOM CELLULE affecte un nom à la cellule définie par les paramètres colonne et ligne.

Vous pouvez accéder à une cellule soit par sa référence absolue — numéro de colonne et numéro de ligne — soit par son nom. Les formules de la zone 4D View peuvent se référer à toute cellule via son nom.

Notes :

Les trois premiers caractères d'un nom de cellule ne doivent pas contenir de chiffre.

Un nom de cellule ne doit pas contenir d'espace (les éventuels espaces contenus dans le paramètre nom seront tronqués par la commande).

Le paramètre facultatif mode permet de définir la manière dont le nouveau nom de la cellule doit être fixé si la cellule dispose déjà d'un ou plusieurs noms. Vous pouvez utiliser les constantes du thème PV Propriétés cellule :

si mode est omis ou si vous passez la constante pv ajouter nom (valeur 0) le nouveau nom est ajouté aux noms éventuellement déjà définis pour la cellule.

si vous passez pv remplacer nom (valeur 1) dans mode, le nouveau nom remplace tous les noms éventuellement déjà définis pour la cellule.

Pour supprimer tous les noms associés à la cellule, passez une chaîne vide ("") dans nom et pv remplacer nom dans mode.

Exemple

Cet exemple permet de nommer la cellule courante. Si elle comporte déjà un nom, l'utilisateur peut le remplacer.

   C_TEXTE($NomCellule)  `Le nom à affecter à la cellule
   C_ENTIER LONG($Colonne)  `N° de colonne de la cellule courante
   C_ENTIER LONG($Ligne)  `N° de ligne de la cellule courante

   PV LIRE CELLULE COURANTE (Zone;$Colonne;$Ligne)  `Récupération coordonnées cellule courante
   $NomCellule:=PV Lire nom cellule (Zone;$Colonne;$Ligne)  `Nom éventuellement déjà attribué

   Si ($NomCellule="")  `La cellule n'est-elle pas déjà nommée ?
      $NomCellule:=Demander("Quel nom voulez-vous affecter à cette cellule ?";"Nouveau_nom")
      Si ($NomCellule#"")  `Le nom a été renseigné
         PV FIXER NOM CELLULE (Zone;$Colonne;$Ligne;$NomCellule)  `Affectation du nom saisi
      Fin de si
   Sinon  `Cellule courante portant déjà un nom
         `Avertissement
      CONFIRMER("Cette cellule porte déjà le nom "+$NomCellule+". Voulez-vous le remplacer ?";"Oui";"Non") 
      Si (OK=1) `L'utilisateur souhaite remplacer le nom
         PV FIXER NOM CELLULE (Zone;$Colonne;$Ligne;$NomCellule;pv remplacer nom)  `Remplacement
      Fin de si 
   Fin de si

Références

PV LIRE LISTE NOMS CELLULES, PV Lire nom cellule.


4D - Documentation   Français   English   German   4D View, Commandes par thèmes   4D View, Liste des commandes   4D View, Constantes par thèmes   Retour   Précédent   Suivant