WR Chercher direct

4D - Documentation   Français   English   German   4D Write, Commandes par thèmes   4D Write, Liste alphabétique des commandes   4D Write, Constantes par thèmes   Retour   Précédent   Suivant

version 6.5


WR Chercher direct (blob; aChercher; motEntier; majuscules) Entier long

ParamètreTypeDescription
blobBLOBBlob
aChercherAlphaChaîne à rechercher
motEntierEntier0=partie de mot
1=mot entier
majusculesEntier0=ignorer majuscules
1=tient compte des majuscules
RésultatEntier longEtat de la recherche

Description

La commande WR Chercher direct permet de rechercher une chaîne de caractères directement dans un BLOB contenant une zone 4D Write sans avoir besoin d'ouvrir la zone, d'où un gain en rapidité.

Si l'expression est trouvée, la fonction retourne la position de la chaine recherchée dans le texte.

Si la recherche a été infructueuse, la fonction retourne -1.

Si blob ne contient pas un document 4D Write, la fonction retourne -2.

Les arguments motEntier et majuscules vous permettent de spécifier la manière dont la recherche va s'effectuer.

Vous pouvez passer dans le paramètre motEntier l'une des constantes suivantes, placées dans le thème WR Paramètres :

Constantes (valeur)Description
wr partie de mot (0)Le mot peut faire partie d'une chaîne de caractères
wr mot entier (1)Pour être trouvé, le mot doit être entouré de caractères séparateurs
(espaces, caractères de ponctuation, etc.)

Vous pouvez passer dans le paramètre majuscules l'une des constantes suivantes, placées dans le thème WR Paramètres :

Constantes (valeur)Description
wr ignorer majuscules (0)La recherche ne tiendra pas compte des majuscules et trouvera
"Bonjour", "bonjour", "BONJOUR"... si vous cherchez "BONJOUR"
wr tenir compte des majuscules (1)La recherche tiendra compte des majuscules et ne trouvera pas
"Bonjour" si vous cherchez "BONJOUR"

Exemple

Cet exemple propose une méthode de recherche par mot-clé sur une sélection d'enregistrements, dans des zones 4D Write associées à des champs BLOB.

Note : Si vous avez opté pour l'association des zones 4D Write à des champs Images, vous pouvez également vous reporter à l'exemple présenté dans la description de la fonction WR Chercher.

Vous possédez une base contenant des recettes de cuisines. Celles-ci ont été enregistrées dans des champs BLOB. Vous désirez pouvoir extraire toutes les recettes contenant un ingrédient particulier. Voici l'exemple vous permettant d'obtenir très rapidement cette sélection :

   Achercher:=Demander("Quel ingrédient désirez-vous rechercher ?")
      `Création d'un ensemble vide dans lequel vont être placés tous les enregistrements
      `contenant l'ingrédient recherché
   ENSEMBLE VIDE([MesRecettes];"SélectionTrouvée")
   TOUT SELECTIONNER([MesRecettes])   `On parcourt toute la sélection de la table
   Tant que (Non(Fin de selection([MesRecettes])))
      Si (WR Chercher direct ([MesRecettes]BlobRecette_;AChercher;wr mot entier;wr tenir compte des majuscules)>0)
            `Lorsque l'ingrédient a été trouvé, l'enregistrement est ajouté à l'ensemble
         ADJOINDRE ELEMENT([MesRecettes];"SélectionTrouvée")
      Fin de si 
      ENREGISTREMENT SUIVANT([MesRecettes])
   Fin tant que 
   UTILISER ENSEMBLE("SélectionTrouvée")
   FORMULAIRE SORTIE([MesRecettes];"Sortie")
   MODIFIER SELECTION([MesRecettes];*)

Référence

WR Chercher.


4D - Documentation   Français   English   German   4D Write, Commandes par thèmes   4D Write, Liste alphabétique des commandes   4D Write, Constantes par thèmes   Retour   Précédent   Suivant