PRINT LABEL

4D - Documentation   Français   English   German   Spanish   Japanese   4D Programmiersprache, Befehle nach Themen   4D Programmiersprache, Befehle alphabetisch   4D Programmiersprache, Konstanten nach Themen   Back   Previous   Next

Version 2004 (Geändert)


PRINT LABEL ({Tabellenname}{; Etikettenname{; * | >}})

ParameterTypBeschreibung
TabellennameTabelleZu druckende Tabelle oder
Haupttabelle ohne Angabe
EtikettennameStringName des gespeicherten Etikettenformats
* | >* Druckdialoge unterdrücken oder
> Eigene Druckparameter beibehalten

Beschreibung

PRINT LABEL druckt für den laufenden Prozess die Datensätze der aktuellen Auswahl von Tabellenname als Etiketten. Tabellenname ist optional. Wird der Parameter nicht angegeben, bezieht sich PRINT LABEL auf die Haupttabelle.

Geben Sie Etikettenname nicht an, benutzt PRINT LABEL das aktuelle Ausgabeformular von Tabellenname. Dieser Befehl gilt nicht für Unterformulare. Weitere Informationen dazu finden Sie im Handbuch 4D Designmodus.

Geben Sie Etikettenname an, können Sie auf den Etiketteneditor oder auf ein gespeichertes Etikettenformular zugreifen.

PRINT LABEL zeigt standardmäßig vor dem Drucken die Druckdialoge an. Bricht der Benutzer einen dieser Dialoge ab, wird der Befehl abgebrochen. Es werden keine Etiketten gedruckt.

Sie können diese Druckdialoge mit den optionalen Parametern Stern (*) oder größer als (>) unterdrücken:

Der Parameter * löst einen Druckauftrag mit den aktuellen Parametern zum Drucken aus.

Der Parameter > löst einen Druckauftrag aus, ohne die aktuellen Druckparameter zu verändern. Diese Einstellung ist hilfreich, um mehrere aufeinanderfolgende Aufrufe von PRINT LABEL unter Beibehaltung der individuell festgelegten Druckparameter auszuführen (z.B. in einer Schleife). Ein Beispiel dazu finden Sie in der Beschreibung zum Befehl PRINT RECORD.

Diese Parameter haben jedoch keine Auswirkung, wenn der Etiketteneditor beteiligt ist.

Ist der Etiketteneditor nicht beteiligt, hat die Variable OK den Wert 1, wenn alle Etiketten gedruckt werden; ansonsten den Wert 0 (Null) (der Benutzer hat z.B. im Druckdialog auf die Schaltfläche Abbrechen geklickt).

Geben Sie den Parameter Etikettenname nicht an, öffnet PRINT LABEL das Standardfenster für die Dokumentenauswahl. Sie können nun das gewünschte Dokument auswählen.

Geben Sie den Parameter Etikettenname an und ist ein Dokument dieses Namens vorhanden, lädt PRINT LABEL die Formatierung für die Etiketten und druckt sie mit den Druckparametern, die bei der Definition der Etiketten festgelegt wurden.

Geben Sie den Parameter Etikettenname an und ist kein Dokument mit diesem Namen vorhanden, ruft der Befehl PRINT LABEL das Standardfenster für die Dokumentenauswahl auf. Sie können dann das gewünschte Dokument auswählen. Möchten Sie sicherstellen, dass nicht doch zufällig ein Dokument mit dem von Ihnen angegebenen Namen existiert, können Sie z.B. den Text, den der Aufruf von Char (1) ergibt, als Argument übergeben. Da dieses Zeichen nicht direkt über die Tastatur erzeugt werden kann, ist es unwahrscheinlich, dass ein Dokument mit diesem Namen existiert.

Hinweis: Ist Tabellenname im Designmodus auf unsichtbar gesetzt, erscheint der Etiketteneditor nicht.

4D Server: Dieser Befehl lässt sich auf 4D Server im Rahmen einer Serverprozedur ausführen. In diesem Kontext müssen Sie folgendes beachten:

Stellen Sie sicher, dass auf dem Server Rechner kein Dialogfenster erscheint, ausser für spezifische Anforderungen. Dazu müssen Sie den Befehl mit dem Parameter * oder > aufrufen.

Die Syntax zum Aufrufen des Etiketteneditors funktioniert nicht mit 4D Server. In diesem Fall wird die Systemvariable OK auf 0 (Null) gesetzt.

Bei einem Druckerproblem, z.B. kein Papier oder Drucker nicht verfügbar, erscheint keine Fehlermeldung.

Beispiele

1. Folgendes Beispiel druckt Etiketten mit dem Ausgabeformular einer Tabelle. Es verwendet zwei Methoden. Die erste setzt das richtige Ausgabeformular und druckt dann die Etiketten:

   ALL RECORDS([Addresses]) ` Wähle alle Datensätze 
   OUTPUT FORM ([Addresses]; "Etikettenausgabe") ` Wähle das Ausgabeformular 
   PRINT LABEL([Addresses]) ` Drucke Etiketten
   OUTPUT FORM ([Addresses];"Ausgabe") ` Stelle Standardausgabeformular wieder her

Die zweite Methode ist die Formularmethode für das Formular "Etikettenausgabe". Es enthält eine Variable mit Namen vLabel, die die Verkettung der Datenfelder erhält. Ist das zweite Addressenfeld (Addr2) leer, entfernt es die Methode. Beachten Sie, dass dieses Task mit dem Etiketteneditor automatisch ausgeführt wird. Die Formularmethode erstellt das Etikett für jeden Datensatz:

      ` [Addresses]; Formularmethode "Etikettenausgabe" 
   Case of
      : (Form event=On Load)
         vLabel:=[Addresses]Name1+" "+[Addresses]Name2
                           +Char(13)+[Addresses]Addr1+Char(13) 
         If ([Addresses]Addr2 # "") 
               vLabel:=vLabel +[Addresses]Addr2+Char(13) 
         End if 
         vLabel:=vLabel+[Addresses]City+", "+[Addresses]State+" "+[Addresses]ZipCode
   End case

2. Folgendes Beispiel lässt den Benutzer die Tabelle [People] suchen und druckt dann automatisch die Etiketten "My Labels":

   QUERY ([People])
   If (OK=1)
      PRINT LABEL ([People];"My Labels";*)
   End if

3. Folgendes Beispiel lässt den Benutzer die Tabelle [People] suchen und dann die zu druckenden Etiketten auswählen:

   QUERY ([People])
   If (OK=1)
      PRINT LABEL ([People];"")
   End if

4. Folgendes Beispiel lässt den Benutzer die Tabelle [People] suchen und zeigt dann den Etiketteneditor, so dass der Benutzer beliebige Etiketten anlegen, sichern, laden und drucken kann:

   QUERY ([People])
   If (OK=1)
      PRINT LABEL ([People];Char(1))
   End if

Referenz

PRINT SELECTION, QR REPORT.


4D - Documentation   Français   English   German   Spanish   Japanese   4D Programmiersprache, Befehle nach Themen   4D Programmiersprache, Befehle alphabetisch   4D Programmiersprache, Konstanten nach Themen   Back   Previous   Next