PLATFORM PROPERTIES

4D - Documentation   Français   English   German   Spanish   Japanese   4D Programmiersprache, Befehle nach Themen   4D Programmiersprache, Befehle alphabetisch   4D Programmiersprache, Konstanten nach Themen   Back   Previous   Next

Version 11 (Geändert)


PLATFORM PROPERTIES (Plattform{; System{; Prozessor{; Sprache}}})

ParameterTypBeschreibung
PlattformNumerisch2 = Mac OS, 3 = Windows
SystemNumerischJe nach eingesetzter Version
ProzessorNumerischProzessorfamilie
SpracheNumerischJe nach eingesetztem System

Beschreibung

Der Befehl PLATFORM PROPERTIES gibt Information über die Art des eingesetzten Betriebssystems, die Version und die Sprache des Betriebssystems sowie den Prozessor Ihres Rechners zurück.

PLATFORM PROPERTIES gibt Informationen zur Umgebung in den Parametern Plattform, System, Prozessor und Sprache zurück.

Plattform gibt das verwendete Betriebssystem an. Dieser Parameter gibt eine der vordefinierten Konstanten zurück:

KonstanteTypWert
Mac OSLange Ganzzahl2
WindowsLange Ganzzahl3

Die in System zurückgegebene Information hängt von der eingesetzten 4D Version ab.

Macintosh Version

Läuft eine Mac OS Version von 4D, gibt der Parameter System einen 32-bit Wert (Lange Ganzzahl) zurück, dessen höherwertiger Teil unbenutzt ist. Der niederwertige Teil ist folgendermaßen aufgebaut:

- Das höherwertige Byte enthält die Hauptversionsnummer,

- Das niederwertige Byte besteht aus zwei "nibbles" (je 4 Bits). Das hohe "nibble" ist die Versionsnummer des Mayor-Update, das niedere "nibble" ist die Versionsnummer des Minor-Update. Beispiel: System 7.5.1 ist codiert als $0751, das ergibt den Dezimalwert 1873.

Hinweis: In 4D können Sie diese Werte mit den numerischen Operatoren % (Restwert oder Modulo) und \ (Ganzzahlige Division) oder den Bit Operatoren entnehmen.

Mit folgender Formel erfahren Sie die Versionsnummer von Mac OS :

   PLATFORM PROPERTIES($vlPlatform;$vlSystem)
   $vlResult:=$vlSystem\256
      `If $vlResult = 8  --> Sie arbeiten mit Mac OS 8.x
      `If $vlResult = 9  --> Sie arbeiten mit Mac OS 9.x
      `If $vlResult = 16  --> Sie arbeiten mit Mac OS 10.x

Windows Version

Läuft eine Windows Version von 4D, gibt der Parameter System einen 32-bit Wert (Lange Ganzzahl) zurück, dessen Bits und Bytes folgendermaßen aufgebaut sind:

Hat das höherwertige Bit den Wert 0, läuft Windows NT, Windows 2000, Windows XP oder Windows Vista. Hat es den Wert 1, läuft Windows 95 oder Windows 98 (beide überholt).

Hinweis: Das höherwertige Bit legt das Vorzeichen für den Wert vom Typ Lange Ganzzahl fest. So müssen Sie in 4D lediglich das Vorzeichen des Werts prüfen; ist es positiv, läuft Windows NT, Windows 2000, Windows XP oder Windows Vista. Sie können auch die Bit Operatoren verwenden.

Das niederwertige Byte gibt die höhere Windows Versionsnummer an. Bei 4 läuft Windows 95, 98 oder Window NT 4. Bei 5 läuft Windows 2000 oder Windows XP. In beiden Fällen erkennen Sie am Vorzeichen, ob NT/2000 läuft. Bei 6 läuft Windows Vista.

Das nächstniedere Byte gibt die niedere Windows Versionsnummer an. Läuft Windows 95, ist der Wert 0.

Hinweis: In 4D können Sie diese Werte mit den numerischen Operatoren % (Restwert oder Modulo) und \ (Ganzzahlige Division) oder den in Version 6 eingeführten Bit Operatoren entnehmen.

Der Parameter Prozesser gibt die Familie des Mikroprozessors des Rechners zurück. Es gibt zwei Werte, die als Konstanten verfügbar sind:

KonstanteTypWert
Intel CompatibleLange Ganzzahl 586
Power PCLange Ganzzahl 406

Durch Kombinieren dieser beiden Parameter können Sie z.B. genau herausfinden, ob der verwendete Rechner von Typ "MacIntel" ist (Plattform=Mac OS und Prozessor=Intel Compatible).

Der Parameter Sprache gibt die aktuelle Sprache des Systems an, auf welchem die Datenbank läuft. Hier die Liste mit den Codes und den zugeordneten Sprachen:

CodeSprache
1Arabisch
2Bulgarisch
3Catalan
4Chinesisch
5Tschechisch
6Dänisch
7Deutsch
8Griechisch
9Englisch
10Spanisch
11Finnisch
12Französisch
13Hebräisch
14Ungarisch
15Isländisch
16Italienisch
17Japanisch
18Koreanisch
19Holländisch
20Norwegisch
21Polnisch
22Portugiesisch
24Rumänisch
25Russisch
26Kroatisch
26Serbisch
27Slovakisch
28Albanisch
29Schwedisch
30Thailändisch
31Türkisch
33Indonesisch
34Ukrainisch
35Weißrussisch
36Slowenisch
37Estländisch
38Lettisch
39Lithauisch
41Farsi (Persisch)
42Vietnamesisch
45Baskisch
54Afrikaans
56Färöisch

Hinweis: Kann der Befehl die Systemsprache nicht identifizieren, wird Wert 9 (Englisch) zurückgegeben.

Beispiel

      ` Projektmethode SHOW OS VERSION 
   PLATFORM PROPERTIES($vlPlatform;$vlSystem;$vlMachine)
   If (($vlPlatform<2) | ($vlPlatform>3))
      $vsPlatformOS:=""
   Else 
      If ($vlPlatform=Windows)
         $vsPlatformOS:=""
         If ($vlSystem<0)
            $winMajVers:=((2^31)+$vlSystem)%256
            $winMinVers:=(((2^31)+$vlSystem)\256)%256
            If ($winMinVers=0)
               $vsPlatformOS:="Windows™ 95"
            Else
               $vsPlatformOS:="Windows™ 98"
            End if
         Else 
            $winMajVers:=$vlSystem%256
            $winMinVers:=($vlSystem\256)%256
            Case of
               : ($winMajVers=4)
                  $vsPlatformOS:="Windows™ NT"
               : ($winMajVers=5)
                  If ($winMinVers=0)
                     $vsPlatformOS:="Windows™ 2000"
                  Else
                     $vsPlatformOS:="Windows™ XP"
                  End if
                  : ($winMajVers=6)
                  $vsPlatformOS:="Windows™ Vista"
            End case
         End if 
         $vsPlatformOS:=$vsPlatformOS+" version "+String($winMajVers)+"."+String($winMinVers)
      Else 
         $vsPlatformOS:="MacOS™ version "
         If (($vlSystem\256) = 16)
            $vsPlatformOS:=$vsPlatformOS+"10"
         Else
            $vsPlatformOS:=$vsPlatformOS+String($vlSystem\256)
         End if
         $vsPlatformOS:=$vsPlatformOS+"."+String(($vlSystem\16)%16)+
                                 (("."+String($vlSystem%16))*Num(($vlSystem%16) # 0))
      End if 
   End if 
   ALERT($vsPlatformOS)

Unter Windows kann die Meldung folgendermaßen aussehen:

Auf Macintosh kann die Meldung folgendermaßen aussehen:

Referenz

Bit Operatoren.

Anwendung des Befehls

File Names and Paths, Multiple Platform Deployment, OnWebConnection, Opening Windows, User Modifiable Forms


4D - Documentation   Français   English   German   Spanish   Japanese   4D Programmiersprache, Befehle nach Themen   4D Programmiersprache, Befehle alphabetisch   4D Programmiersprache, Konstanten nach Themen   Back   Previous   Next