DELETE RESOURCE

4D - Documentation   Français   English   German   Spanish   Japanese   4D Programmiersprache, Befehle nach Themen   4D Programmiersprache, Befehle alphabetisch   4D Programmiersprache, Konstanten nach Themen   Back   Previous   Next

Version 6.0


DELETE RESOURCE (ResTyp; ResNR{; ResDatei})

ParameterTypBeschreibung
ResTypStringRessourcentyp mit 4 Zeichen
ResNRNumerischKennummer der Ressource
ResDateiDokRefReferenznummer der Ressourcendatei,
ohne Angabe aktuelle Ressourcendatei

Beschreibung

Der Befehl DELETE RESOURCE löscht die Ressource vom Typ ResTyp mit der Nummer ResNR.

Ist die Ressource nicht vorhanden, hat der Befehl keine Auswirkung. Die OK Variable wird auf 0 (Null) gesetzt. Wird die Ressource gefunden und entfernt, wird die OK Variable auf 1 gesetzt.

Übergeben Sie in ResDatei eine gültige Referenznummer für die Ressourcendatei, wird die Ressource nur in dieser Datei gesucht. Übergeben Sie ResDatei nicht, wird die Ressource in der aktuellen geöffneten Ressourcendatei gesucht.

Warnung: Löschen Sie KEINE Ressourcen, die zu 4D oder anderen Systemdateien gehören. Das kann zu unerwünschten Systemfehlern führen.

Beispiele

1. Folgendes Beispiel löscht die Ressource "STR#" ID=20000:

      ` Beachten Sie, dass dieses Beispiel die erste gefundene Ressource 
      ` "STR#" ID=20000 in jeder aktuell geöffneten Ressourcendatei löscht:
   DELETE RESOURCE ("STR#";20000)

2. Folgendes Beispiel löscht die Ressource "STR#" ID=20000, wenn sie in einer spezifischen Ressourcendatei gefunden wird:

      ` Beachten Sie, daß dieses Beispiel die Ressource "STR#" ID=20000 nur löscht, 
      ` wenn sie in der Ressourcendatei $vhResFile vorhanden ist:
   DELETE RESOURCE ("STR#";20000;$vhResFile)
      ` Gibt es diese Ressource auch in einer anderen aktuell geöffneten
      ` Ressourcendatei, wird sie nicht gelöscht

3. Die Projektmethode DELETE RESOURCES OF TYPE löscht alle Ressourcen vom angegebenen Typ (zweiter Parameter) aus der angegebenen Ressourcendatei (erster Parameter):

      ` Projektmethode DELETE RESOURCES OF TYPE 
      ` DELETE RESOURCES OF TYPE ( Zeit ; String )
      ` DELETE RESOURCES OF TYPE ( ResDatei ; ResTyp )
   
   C_TIME($1)
   C_STRING(4;$2)

   RESOURCE LIST($2;$aiResID;$asResName;$1)
   If(OK=1)
      For($vlElem;1;Size of array($aiResID))
         DELETE RESOURCE($2;$aiResID{$vlElem};$1)
      End for
   End if

Ist diese Projektmethode in die Datenbank integriert, können Sie schreiben:

      ` Lösche alle Ressourcen vom Typ "PREF" aus der Ressourcendatei $vhResFile
   DELETE RESOURCES OF TYPE ($vhResFile;"PREF")

4. Die Projektmethode DELETE RESOURCE BY NAME löscht eine Ressource (eines spezifischen Typs) deren Name bekannt ist:

      ` Projektmethode DELETE RESOURCE BY NAME
      ` DELETE RESOURCE BY NAME ( Zeit ; String ; String )
      ` DELETE RESOURCE BY NAME ( ResDatei ; Restyp ; ResName )
   
   C_TIME($1)
   C_STRING(4;$2)
   C_STRING(255;$3)

   RESOURCE LIST($2;$aiResID;$asResName;$1)
   If(OK=1)
      $vlElem:=Find in array($asResName;$3)
      If($vlElem>0)
         DELETE RESOURCE($2;$aiResID{$vlElem};$1)
      End for
   End if

Ist diese Projektmethode in die Datenbank integriert, können Sie schreiben:

      `Lösche aus der Ressourcendatei $vhResFile die Ressource "PREF" mit dem Namen "Standardeinstellungen":
   DELETE RESOURCE BY NAME ($vhResFile;"PREF";"Standardeinstellungen")

Referenz

RESOURCE LIST, SET RESOURCE PROPERTIES.

Systemvariablen und Mengen

Wurde die Ressource gelöscht, wird die OK Variable auf 1 gesetzt, sonst auf 0 (Null).


4D - Documentation   Français   English   German   Spanish   Japanese   4D Programmiersprache, Befehle nach Themen   4D Programmiersprache, Befehle alphabetisch   4D Programmiersprache, Konstanten nach Themen   Back   Previous   Next