PV FIELDS LIST TO CELLS

4D - Documentation   Français   English   German   4D View, Befehle nach Themen   4D View, Befehle alphabetisch   4D View, Konstanten   Back   Previous   Next

Version 6.8


PV FIELDS LIST TO CELLS (Bereich; Richtung; Spalte; Zeile; Umwandlung; Master; Tabelle; Felder)

ParameterTypBeschreibung
BereichLange Ganzzahl4D View Bereich
RichtungGanzzahl0 = Zeile; 1 = Spalte
SpalteArrayArray mit Spaltennummer Startzelle
ZeileArrayArray mit Zeilennummer Startzelle
UmwandlungArray0 = Originaltyp; 1 = Setze in Text
MasterGanzzahlNummer Mastertabelle
TabelleArrayNummer Tabelle
FelderArrayFeldnummern

Beschreibung

Der Befehl PV FIELDS LIST TO CELLS arbeitet wie PV FIELD TO CELLS, jedoch für mehrere Felder.

Hinweis: Der Parameter Richtung arbeitet hier anders als für die Befehle PV GOTO NEXT CELL und PV GET NEXT FREE CELL, wo jede Richtung möglich ist. Für PV CELLS TO ARRAY läuft Richtung entweder nach rechts (0 = Zeile) oder nach unten (1=Spalte).

Mit dem Parameter Umwandlung können Sie den Datentyp des Zelleninhalts in Text konvertieren. Der ursprüngliche Typ muss natürlich kompatibel sein. Eine Zelle vom Typ BLOB oder Bild lässt sich nicht in Text konvertieren.

Die Arrays Tabelle und Felder enthalten die Nummern der Tabellen und Quellfelder.

Die Parameter Spalte und Zeile enthalten die Spalten- und Zeilennummern der jeweiligen Startzelle.

Sie können den Befehl für eine Tabelle verwenden, die mit einer Mastertabelle verknüpft ist. Die Verknüpfung muss automatisch sein und von der Tabelle Master zur Tabelle mit dem Feld für die Anzeige führen, definiert über die Arrays Tabelle und Felder.

Befehle wie PV ADD DYNAMIC FIELDS erhalten eine dynamische Verknüpfung mit der Datenbank, d.h. Änderungen werden übernommen. Dagegen werden im 4D View Bereich geänderte Werte, die über den Befehl PV FIELDS LIST TO CELLS entnommen werden, nicht im Datensatz übernommen.

Beispiel

Wir verwenden wieder das Beispiel zum Befehl PV FIELD TO CELLS für ein Eingabeformular, das für einen Datensatz aus der Tabelle [Contacts] geladen wird. Dieses Mal bearbeiten wir drei Felder gleichzeitig.

Über eine automatische Verknüpfung von der Mastertabelle [Contacts] zur Tabelle [Titles] können wir in einem dynamischen Feld die Bezeichnung der Funktion für jeden Kunden über ihren Code erhalten, welcher im Startfeld der Verknüpfung als Ganzzahl gesichert ist. Wir zeigen die dritte Spalte von Bedeutung an. Das ist Spalte E, da wir von Spalte C aus starten.

   C_INTEGER($Master)  `Nummer Mastertabelle
   C_INTEGER($Index)  `Durchlaufe Index

   $Master:=Table(->[Contacts])  `Nummer Mastertabelle:  Kunden (für alle Spalten)

   ARRAY LONGINT($ArrayColumns;3)  `Spaltennummer Startzelle
   ARRAY LONGINT($ArrayRows;3)  `Zeilennummer Startzelle
   ARRAY INTEGER($ConversionArray;3)  `0 für Originaltyp oder 1 für Umwandlung in Text
   ARRAY INTEGER($TablesArray;3)  `Tabellennummern
   ARRAY INTEGER($FieldsArray;3)  `Feldnummern

   For ($Index;1;3)
      $ArrayColumns{$Index}:=$Index+2  `Spalten C bis E
      $ArrayRows{$Index}:=2  `Starte mit 2. Zeile
      $ConversionArray{$Index}:=0  `Erhalte Original Feldtypen
   End for

      `Zu erhaltende Tabellen und Felder
   $TablesArray{1}:=Table(->[Contacts])  `Nummer der Tabelle [Contacts]
   $FieldsArray{1}:=Field(->[Contacts]ContactName)  `Nummer des Datenfeldes Name

   $TablesArray{2}:=Table(->[Contacts])  `Nummer der Tabelle Contacts
   $FieldsArray{2}:=Field(->[Contacts]ContactFirstName)  `Nummer des Feldes Vorname

   $TablesArray{3}:=Table(->[Titles])  `Nummer der Tabelle Titles (verknüpft)
   $FieldsArray{3}:=Field(->[Titles]Label) 
                      `Nummer des Feldes Label (Direktor, Sekretärin, Entwickler)

      `Erhalte die dazugehörige Auswahl Kontakte
   RELATE MANY([Clients]code) 

      `Aktualisiere den 4D View Bereich mit den Feldern Name, Vorname und Title
   PV FIELDS LIST TO CELLS(Bereich;1;$ArrayColumns;$ArrayRows;
                     $ConversionArray;$Master;$TablesArray;$FieldsArray)

Referenz

PV ADD DYNAMIC FIELDS, PV ARRAY TO CELLS, PV FIELD TO CELLS.


4D - Documentation   Français   English   German   4D View, Befehle nach Themen   4D View, Befehle alphabetisch   4D View, Konstanten   Back   Previous   Next