PV SET CELL CONTROL

4D - Documentation   Français   English   German   4D View, Befehle nach Themen   4D View, Befehle alphabetisch   4D View, Konstanten   Back   Previous   Next

Version 6.8


PV SET CELL CONTROL (Bereich; Spalte; Zeile; Typ; Name; Methode; Titel)

ParameterTypBeschreibung
BereichLange Ganzzahl4D View Bereich
SpalteLange GanzzahlSpaltennummer Zelle
ZeileLange GanzzahlZeilennummer Zelle
TypGanzzahlKontrolltyp
NameStringName der Variablen für Kontrollmanagement
MethodeStringName Callback Methode
TitelStringKontrolltitel

Beschreibung

Der Befehl PV SET CELL CONTROL setzt ein "Kontrollobjekt" in der Zelle, definiert durch Spalte und Zeile. Ein Kontrollobjekt ist ein Objekt vom Typ Schaltfläche, Kontrollkästchen, Optionsfeld, DropDown Liste oder Combo Box in einer Zelle.

Enthält die Zelle bereits ein Kontrollobjekt, wird es gelöscht und durch das neue ersetzt. Sein Typ spielt dabei keine Rolle.

Typ gibt den Typ des Kontrollobjekts in der Zelle an. Für diesen Parameter verwenden Sie eine Konstante unter dem Thema PV Steuerung.

Name ist der Name einer 4D Variablen oder eines Arrays. Ist das Kontrollobjekt Drop-Down Liste und Combo Box, übergeben Sie hier Namen eines Arrays mit den Werten für das Objekt.

Methode enthält den Namen der Callback Methode, die mit dem Kontrollobjekt verknüpft ist. Weitere Informationen zu Callback Methoden finden Sie im Abschnitt Einleitung zu PV Bereich.

Titel enthält die Bezeichnung der Schaltfläche, des Kontrollkästchens, etc. Für diesen Parameter übergeben Sie bei DropDown Listen oder Combo Boxen einen Leerstring " ".

Beispiele

Mit nachfolgender Methode können Sie verschiedene Kontrolltypen ansehen:

Standardschaltfläche in C3:

   C_LONGINT(vStandardButton)  `Standardschaltfläche
     PV SET CELL CONTROL 
   (Bereich;3;3;pv control push button ;"vStandardButton";"CallbackButton";"Button")
            
        `Methode CallbackButton
   C_LONGINT($1)  `4D View Bereich
   C_LONGINT($2)  `Spaltennummer
   C_LONGINT($3)  `Zeilennummer
   C_POINTER($4)  `Zeiger auf das geklickte Objekt
   ALERT("Name der Callback Methode: "+Current method name)

Optionsfeld in E3, E4, E5:

   C_LONGINT(vRadio1;vRadio2;vRadio3)  `Optionsfelder
   vRadio1:=1
   vRadio2:=0
   vRadio3:=0
   PV SET CELL CONTROL 
   (Bereich;5;3;pv control radio button ;"vRadio1";"CallbackRadio";"Tag")
   PV SET CELL CONTROL
    (Bereich;5;4;pv control radio button ;"vRadio2";"CallbackRadio";"Monat")
   PV SET CELL CONTROL 
   (Bereich;5;5;pv control radio button ;"vRadio3";"CallbackRadio";"Jahr")
        `Methode CallbackRadio
   C_LONGINT($1)  `4D View Bereich
   C_LONGINT($2)  `Spaltennummer
   C_LONGINT($3)  `Zeilennummer
   C_POINTER($4)  `Zeiger auf das geklickte Objekt
   C_STRING(6;$Value)
   Case of 
        : ($4=(->vRadio1))
         vRadio2:=0
             vRadio3:=0
             $Value:="Day"
         : ($4=(->vRadio2))
             vRadio1:=0
             vRadio3:=0
             $Value:="Month"
            : ($4=(->vRadio3))
             vRadio1:=0
             vRadio2:=0
             $Value:="Year"
   End case 
   PV SET CELL TEXT VALUE ($1;($2+1);3;$Value)

Kontrollkästchen in E7, E8, E9:

   C_LONGINT(vCheckBox1;vCheckBox2;vCheckBox3)  `Kontrollkästchen zum Prüfen
   vCheckBox1:=0
     vCheckBox2:=0
     vCheckBox3:=0
    PV SET CELL CONTROL 
   (Bereich;5;7;pv control check box ;"vCheckBox1";"CallbackCheckBox";"Anfänger")
     PV SET CELL CONTROL 
   (Bereich;5;8;pv control check box ;"vCheckBox2";"CallbackCheckBox";"Geübt")
     PV SET CELL CONTROL 
   (Bereich;5;9;pv control check box ;"vCheckBox3";"CallbackCheckBox";"Profi")
        `Methode CallbackCheckBox
   C_LONGINT($1)  `4D View Bereich
   C_LONGINT($2)  `Spaltennummer
   C_LONGINT($3)  `Zeilennummer
   C_POINTER($4)  `Zeiger auf das geklickte Objekt
   C_TEXT($Value)
   If (vCheckBox1=1)
        $Value:="Beginner"
   End if 
   If (vCheckBox2=1)
        If ($Value#"")
             $Value:=$Value+" + "
        End if 
        $Value:=$Value+"Intermediate"
   End if 
   If (vCheckBox3=1)
        If ($Value#"")
             $Value:=$Value+" + "
        End if 
        $Value:=$Value+"Expert"
   End if 
   PV SET CELL TEXT VALUE ($1;($2+1);7;$Value)

DropDown Liste in C5:

   ARRAY TEXT(DropdownListArray;5)  `Für DropDown Liste
   DropdownListArray{1}:="Montag"
     DropdownListArray{2}:="Dienstag"
     DropdownListArray{3}:="Mittwoch"
     DropdownListArray{4}:="Donnerstag"
     DropdownListArray{5}:="Freitag"
     DropdownListArray:=3  `Standard auf Mittwoch
     PV SET CELL CONTROL 
   (Bereich;3;5;pv control drop down ;"DropdownListArray";"CallbackDropList";"")
        `Methode CallbackDropList
   C_LONGINT($1)  `4D View Bereich
   C_LONGINT($2)  `Spaltennummer
   C_LONGINT($3)  `Zeilennummer
   C_POINTER($4)  `Zeiger auf das geklickte Objekt
   PV SET CELL TEXT VALUE ($1;3;6;DropdownListArray{DropdownListArray})

Combo Box in C7:

   ARRAY TEXT(ComboArray;5)  `Für Combo Box Liste
   ComboArray{1}:="Montag"
    ComboArray{2}:="Dienstag"
     ComboArray{3}:="Mittwoch"
     ComboArray{4}:="Donnerstag"
     ComboArray{5}:="Freitag"
     ComboArray:=5  `Standard auf Freitag
     PV SET CELL CONTROL 
   (Bereich;3;7;pv control combo box ;"ComboArray";"CallbackCombo";"")
        `Methode CallbackCombo
   C_LONGINT($1)  `4D View Bereich
   C_LONGINT($2)  `Spaltennummer
   C_LONGINT($3)  `Zeilennummer
   C_POINTER($4)  `Zeiger auf das geklickte Objekt
   PV SET CELL TEXT VALUE ($1;3;8;ComboArray{0})

Referenz

PV GET CELL CONTROL, PV Get cell value type.

Konstanten

Thema PV Steuerung.


4D - Documentation   Français   English   German   4D View, Befehle nach Themen   4D View, Befehle alphabetisch   4D View, Konstanten   Back   Previous   Next