Current date

4D - Documentation   Français   English   German   Español   English   4D v11 SQL, Comandos por temas   4D v11 SQL, Lista alfabética de comandos   4D v11 SQL, Constantes por temas   Regresar   Anterior   Siguiente

versión 3


Current date {(*)} Fecha

ParámetroTipoDescripción
*Devuelve la fecha actual del servidor
ResultadoFechaFecha actual

Descripción

El comando Current date devuelve la fecha actual tal como está definida en el reloj del sistema.

4D Server: Si usted utiliza el parámetro asterisco (*) cuando ejecuta esta función en un equipo 4D Client, la función devuelve la fecha actual del servidor.

Ejemplos

1. El siguiente ejemplo muestra una ventana de alerta que contiene la fecha actual:

   ALERT("La fecha es " + String(Current date)+".")

2. Si escribe una aplicación para el mercado internacional, podría necesitar saber si la versión de 4D con la que se ejecuta su aplicación funciona con fechas en formato MM/DD/AAAA (versión US) o DD/MM/AAAA (Versión Francesa). Esta información es útil para personalizar la entrada de datos a los campos.

El siguiente método de proyecto le permite hacerlo:

      ` Función global de formato de datos del sistema
      ` Formato de datos del sistema -> Cadena
      ` Formato de datos del sistema -> Formato de datos 4D por defecto

   C_STRING(31;$0;$vsFecha;$vsMDA;$vsMes;$vsDia;$vsAno)
   C_LONGINT($1;$vlPos)
   C_DATE($vdFecha)

      ` Obtener una fecha donde los valores de mes, día, y años sean diferentes
   $vdFecha:=Current date
   Repeat
      $vsMes:=String(Month of($vdFecha))
      $vsDia:=String(Day of($vdFecha))
      $vsAno:=String(Year of($vdFecha)%100)
      If (($vsMes=$vsDia) | ($vsMes=$vsAno) | ($vsDia=$vsAno))
         vOK:=0
         $vdFecha:=$vdFecha+1
      Else
         vOK:=1
      End if
   Until (vOK=1)
   $0:=""  ` Inicialización del resultado de la función
   $vsFecha:=String($vdFecha)
   $vlPos:=Position("/";$vsFecha)  ` Encontrar el primer separador / en la cadena ../../..
   $vsMDA:=Substring($vsFecha;1;$vlPos-1)  ` Extraer los primeros dígitos de la fecha
   $vsFecha:=Substring($vsFecha;$vlPos+1)  ` Eliminar los primeros dígitos y el primer separador /
   Case of
      : ($vsMDA=$vsMes)  ` Los dígitos expresan el mes
         $0:="MM"
      : ($vsMDA=$vsDia)  ` Los dígitos expresan el día
         $0:="DD"
      : ($vsMDA=$vsAno)  ` Los dígitos expresan el año
         $0:="AAAA"
   End case
   $0:=$0+"/"  ` Comenzar a construir el resultado de la función
   $vlPos:=Position("/";$vsFecha)  ` Encontrar el segundo separador en la cadena ../..
   $vsMDA:=Substring($vsFecha;1;$vlPos-1)  ` Extraer los dígitos siguientes de la fecha
   $vsFecha:=Substring($vsFecha;$vlPos+1)  ` Reducir la cadena a los últimos dígitos de la fecha
   Case of
      : ($vsMDA=$vsMes)  ` Los dígitos expresan el mes
         $0:=$0+"MM"
      : ($vsMDA=$vsDia)  ` Los dígitos expresan el día
         $0:=$0+"DD"
      : ($vsMDA=$vsAno)  ` Los dígitos expresan el año
         $0:=$0+"AAAA"
   End case
   $0:=$0+"/"  ` Comenzar a construir el resultado de la función
   Case of
      : ($vsFecha=$vsMes)  ` Los dígitos expresan el mes
         $0:=$0+"MM"
      : ($vsFecha=$vsDia)  ` Los dígitos expresan el día
         $0:=$0+"DD"
      : ($vsFecha=$vsAno)  ` Los dígitos expresan el año
         $0:=$0+"AAAA"
   End case
      ` En este momento $0 es igual a MM/DD/AAAA o DD/MM/AAAA o...

Ver también

Day of, Month of, Operadores de fechas, Year of.


4D - Documentation   Français   English   German   Español   English   4D v11 SQL, Comandos por temas   4D v11 SQL, Lista alfabética de comandos   4D v11 SQL, Constantes por temas   Regresar   Anterior   Siguiente