RECEIVE PACKET

4D - Documentation   Français   English   German   Español   English   4D v11 SQL, Comandos por temas   4D v11 SQL, Lista alfabética de comandos   4D v11 SQL, Constantes por temas   Regresar   Anterior   Siguiente

versión 11 (Modificado)


RECEIVE PACKET ({docRef; }varRecep; carParada | numCars)

ParámetroTipoDescripción
docRefDocRefNúmero de referencia del documento o
canal actual (puerto serial o documento)
varRecepVar cadena | Var BLOBVariable para recibir datos
carParada | numCarsAlfa | NúmeroCarácter(es) en el(los) cual(es) detener la
recepción o número de caracteres a
recibir

Descripción

RECEIVE PACKET lee los caracteres desde un puerto serial o desde un documento.

Si docRef se especifica, el comando lee los caracteres desde un documento abierto por la función Open document, Create document o Append document. Si se omite docRef, este comando lee caracteres del puerto serial o del documento abierto utilizando SET CHANNEL.

Sin importar la fuente, los caracteres leídos se devuelven en la variable varRecep, la cual debe ser una variable de tipo Texto, Alfa o BLOB. Si los caracteres han sido enviados por el comando RECEIVE PACKET, el tipo debe corresponder al del paquete enviado.

Notas:

En modo no Unicode (modo contabilidad) las variables alfa aceptan hasta 255 caracteres y tienen un tamaño fijo y las variables tipo Texto no tienen un tamaño fijo y pueden aceptar 32 000

Cuando el paquete recibido es de tipo BLOB, el comando no tiene en cuenta ningún conjunto de caracteres definido por el comando USE CHARACTER SET. Se devuelve el BLOB sin ninguna modificación.

Para leer un número particular de caracteres, pase este número en numCars. Si la variable recepVar es de tipo Texto, en una sola llamada usted puede leer hasta 2 GB de texto en modo Unicode o 32 000 caracteres en modo no Unicode (en este caso, para especificar el número máximo de caracteres, puede pasar la constante MAXTEXTLENBEFOREV11 en numCars.

Para leer caracteres hasta que encuentre una cadena particular (compuesta de uno o más caracteres), pase esta cadena en carParada(la cadena no se devuelve en varRecep).

En este caso, si no se encuentra el carácter cadena especificado por carParada:

Cuando RECEIVE PACKET lee datos en un documento, se detendrá la lectura al final del documento.

Cuando RECEIVE PACKET lee datos de un puerto serial, el comando se ejecutará indefinidamente hasta que el timeout (si hay) haya pasado (ver SET TIMEOUT) o hasta que el usuario interrumpa la recepción (ver a continuación).

Durante la ejecución de RECEIVE PACKET, el usuario puede interrumpir la recepción presionando Ctrl-Alt-Mayús (Windows) o Comando-Opción-Mayús (Macintosh). Esta interrupción genera un error -9994 que puede interceptar con un método instalado utilizando ON ERR CALL. Generalmente, sólo tendrá que administrar la interrupción de una recepción en el momento de una comunicación sobre un puerto serial.

Durante la lectura de un documento, el primer RECEIVE PACKET comienza por leer el principio del documento. La lectura de cada paquete subsiguiente comienza con el carácter después del último carácter leído.

Nota: Este comando es útil con un documento abierto con SET CHANNEL. Por el contrario, para un documento abierto con Open document, Create document y Append document, puede utilizar los comandos Get document position y SET DOCUMENT POSITION para obtener y cambiar la ubicación en el documento donde ocurrirá la próxima escritura (SEND PACKET) o lectura (RECEIVE PACKET).

Cuando intente leer después del final de un archivo RECEIVE PACKET devuelve los datos leídos hasta ese punto y la variable OK tomará el valor 1. Luego, el siguiente RECEIVE PACKET devolverá una cadena vacía y la variable OK tomará el valor cero.

Nota: en modo no Unicode (compatibilidad) cuando utiliza el comando RECEIVE PACKET para leer caracteres de un documento Windows y no quiere utilizar mapas ASCII para convertir los caracteres Windows en caracteres Mac OS, puede utilizar la función Win to Mac.

Ejemplos

1. El siguiente ejemplo lee 20 caracteres de un puerto serial en la variable recupVeinte:

   RECEIVE PACKET (recupVeinte; 20)

2. El siguiente ejemplo lee datos del documento referenciado por la variable miDoc en la variable vData. El comando lee hasta que encuentra un retorno de carro:

   RECEIVE PACKET (miDoc;vData;Char (Carriage Return))

3. El siguiente ejemplo lee datos desde el documento referenciado por la variable miDoc en la variable vData. El comando lee hasta que encuentra una etiqueta HTML de fin de tabla </TD>:

   RECEIVE PACKET (miDoc;vData;"</TD>")

4. El siguiente ejemplo lee datos de un documento y los coloca en campos. Los datos se almacenan como campos de longitud fija. El método llama a una subrutina para eliminar espacios (espacios al final de la cadena). La subrutina sigue el método:

   $vhDocRef := Open document ("";"TEXT")  ` Apertura de un documento de tipo TEXTO 
   If (OK=1)  ` Si el documento está abierto
      Repeat  ` Bucle hasta que no haya más datos 
         RECEIVE PACKET ($vhDocRef; $Var1; 15)  ` Lectura de 15 caracteres 
         RECEIVE PACKET ($vhDocRef; $Var2; 15)  ` Hace lo mismo para el segundo campo 
         If (($Var1#"") |($Var2#""))  ` Si por lo menos uno de los campos no está vacío
            CREATE RECORD([Personas])  ` Crear un nuevo registro 
            [Personas]Nombre := Strip ($Var1)  ` Guardar el nombre 
            [Personas]Apellido:= Strip ($Var2)  ` Guardar el apellido 
            SAVE RECORD([Personas])  ` Guardar el registro 
         End if 
      Until (OK =0) 
      CLOSE DOCUMENT ($vhDocRef)  ` Cierre del documento 
   End if

Los espacios al final de los datos son eliminados por el siguiente método, llamado Elimina:

   For ($i; Length ($1); 1; -1)  ` Bucle desde el final de la cadena al inicio 
      If ($1[[$i]] # " ")  ` Si no es un espacio… 
         $i := -$i  ` Forzar el bucle a detenerse 
      End if 
   End for 
   $0 := Delete string ($1; -$i; Length ($1))  ` Borrar los espacios

Ver también

Get document position, RECEIVE PACKET, SEND PACKET, SET DOCUMENT POSITION, SET TIMEOUT, USE CHARACTER SET.

Variables o conjuntos sistema

Después de un llamado a RECEIVE PACKET, la variable sistema OK toma el valor 1 si el paquete se recibe sin errores. De lo contrario, la variable sistema OK toma el valor 0.


4D - Documentation   Français   English   German   Español   English   4D v11 SQL, Comandos por temas   4D v11 SQL, Lista alfabética de comandos   4D v11 SQL, Constantes por temas   Regresar   Anterior   Siguiente