Open window

4D - Documentation   Français   English   German   Español   English   4D v11 SQL, Comandos por temas   4D v11 SQL, Lista alfabética de comandos   4D v11 SQL, Constantes por temas   Regresar   Anterior   Siguiente

versión 2004 (Modificado)


Open window (izquierda; superior; derecha; inferior{; tipo{; título{; casillaCerrar}}}){ RefVen }

ParámetroTipoDescripción
izquierdaNuméricoCoordenada global izquierda del interior de la ventana
superiorNuméricoCoordenada global superior del interior de la ventana
derechaNuméricoCoordenada global derecha del interior de la ventana
inferiorNuméricoCoordenada global inferior del interior de la ventana
tipoNuméricoTipo de la ventana
títuloAlfaTítulo de la ventana
casillaCerrarAlfaMétodo a llamar en caso de doble clic del menú
Control o de clic en la casilla Cerrar
ResultadoRefVenNúmero de referencia de la ventana

Descripción

Open window abre una nueva ventana cuyas dimensiones son definidas por los cuatro primeros parámetros:

izquierda es la distancia en píxeles desde el lado izquierdo de la ventana de la aplicación y el costado interior izquierdo de la ventana.

superior es la distancia en píxeles entre la altura de la ventana de la aplicación y el borde superior del interior de la ventana.

derecha es la distancia en píxeles entre el lado izquierdo de la ventana de la aplicación y el costado interior derecho de la ventana.

inferior es la distancia en píxeles desde la parte superior de la ventana de la aplicación y borde interior inferior de la ventana.

Si pasa -1 en derecha e inferior, le indica a 4D que redimensione automáticamente la ventana si se cumplen las siguientes condiciones:

Usted ha diseñado un formulario y definido sus opciones de redimensionamiento en la ventana de propiedades del formulario en el entorno Diseño

Antes de llamar Open window, usted seleccionó el formulario utilizando el comando INPUT FORM, al cual pasó el parámetro opcional *.

Importante: Este dimensionamiento automático de la ventana ocurrirá únicamente si realiza una llamada previa a INPUT FORM para el formulario a mostrar en la ventana, y si le pasa el parámetro opcional *.

El parámetro tipo es opcional y define el tipo de ventana que quiere mostrar, y corresponde a las diferentes ventanas presentadas en la sección Window Types. Si el tipo pasado es negativo, la ventana será flotante. Si el tipo no se especifica, el tipo 1 se utiliza por defecto.

El parámetro titulo indica el título opcional de la ventana

Si pasa una cadena vacía ("") en titulo, le indica a 4D que utilice los valores de introducidos en el área Nombre de la ventana de la ventana de Propiedades del formulario en el entorno Diseño para el título del formulario a mostrar en la ventana.

Importante: El título por defecto del formulario se aplicará a la ventana únicamente se llama previamente al comando INPUT FORM para el formulario a mostrar y le pasa el parámetro opcional *.

El parámetro casillaCerrar es opcional y designa el método para cerrar la ventana. Si se especifica este parámetro, la casilla del menú Control (Windows) o la casilla Cerrar (Macintosh) se añade a la ventana. Cuando el usuario hace doble clic en la casilla de menú Control (Windows) o clic en la Casilla cerrar (Macintosh), se llama al método pasado en casillaCerrar.

Nota: también puede administrar el cierre de la ventana desde el método del formulario mostrado en la ventana cuando ocurre un evento On Close Box. Para mayor información, consulte el comando Form event.

Si se abre más de una ventana para un proceso, la última ventana abierta es la ventana activa (del primer plano) para ese proceso. Sólo puede modificarse la información dentro de la ventana activa. Todas las demás ventanas pueden ser visualizadas. Cuando el usuario digita, la ventana activa siempre pasará al primer plano, si aún no está ahí.

Los formularios se muestran al interior de una ventana abierta. El texto pasado al comando MESSAGE también aparece en la ventana.

Ejemplos

1. El siguiente método de proyecto abre una ventana centrada en la ventana en la ventana principal (Windows) o en la pantalla principal (Macintosh). Note que puede aceptar dos, tres, o cuatro parámetros:

      ` Método de proyecto OPEN CENTERED WINDOW 
      ` $1 – Ancho de la ventana 
      ` $2 – Alto de la ventana 
      ` $3 – Tipo de la ventana (opcional) 
      ` $4 – Título de la ventana  (opcional) 
   $SW:=Screen width\2 
   $SH:=(Screen height\2)
   $WW:=$1\2 
   $WH:=$2\2 
   Case of 
      : (Count parameters=2) 
         Open Window ($SW-$WW;$SH-$WH;$SW+$WW;$SH+$WH) 
      : (Count parameters=3) 
         Open Window ($SW-$WW;$SH-$WH;$SW+$WW;$SH+$WH;$3) 
      : (Count parameters=4) 
         Open Window ($SW-$WW;$SH-$WH;$SW+$WW;$SH+$WH;$3;$4) 
   End case

Una vez escrito el método de proyecto, puede utilizarlo de esta forma:

   OPEN CENTERED WINDOW (400;250;Movable dialog box;"Actualizar archivos")
   DIALOG([Tabla de herramientas];"UPDATE OPTIONS")
   CLOSE WINDOW
   If (OK=1)
      ` ...
   End if

2. El siguiente ejemplo abre una ventana flotante que tiene un casilla de menú Control (Windows) o una casilla de cerrar (Macintosh). La ventana se abre en la esquina superior derecha de la ventana de la aplicación.

   Open window(Screen width-149;33;Screen width-4;178;- Palette window;"";"casillaCerrar")
   DIALOG([Dialogos];"Paleta de colores")

El método casillaCerrar llama al comando CANCEL:

   CANCEL 

3. El siguiente ejemplo abre una ventana cuyo tamaño y título provienen de las propiedades del formulario mostrado en la ventana:

   INPUT FORM([Clientes];"Añadir registros";*)
   Open window(10;80;-1;-1;Plain window;"")
   Repeat
      ADD RECORD([Clientes])
   Until (OK=0)

Recuerde: Para que la función Open window utilice automáticamente las propiedades del formulario, debe llamar a INPUT FORM con el parámetro opcional * y las propiedades del formulario deben haber sido definidas en función de esta utilización en el entorno Diseño.

4. Este ejemplo ilustra el mecanismo de "retraso" de mostrar ventanas bajo Mac OS X:

    $miVentana:=Open window(10;10;400;400;Sheet window)
      `Por el momento, se crea la ventana pero permanece oculta
   DIALOG([Tabla];"formDial")
      `El evento On Load se genera luego se muestra la ventana; "desciende" de debajo de la barra de título

Ver también

CLOSE WINDOW, Open external window, Open form window.


4D - Documentation   Français   English   German   Español   English   4D v11 SQL, Comandos por temas   4D v11 SQL, Lista alfabética de comandos   4D v11 SQL, Constantes por temas   Regresar   Anterior   Siguiente