Command name

4D - Documentation   Français   English   German   Español   English   4D v11 SQL, Comandos por temas   4D v11 SQL, Lista alfabética de comandos   4D v11 SQL, Constantes por temas   Regresar   Anterior   Siguiente

versión 6.0


Command name (comando) Alfa

ParámetroTipoDescripción
comandoNuméricoNúmero del comando
ResultadoAlfaNombre del comando traducido

Descripción

El comando Command name devuelve el nombre literal del comando cuyo número se pasa en comando.

4D integra una traducción dinámica de palabras claves, constantes y nombres de comandos utilizados en sus métodos. Por ejemplo, si utiliza la versión inglesa de 4D, usted escribe:

   DEFAULT TABLE ([MiTabla])
   ALL RECORDS ([MiTabla])

Este mismo código, si se abre con la versión francesa de 4D, será traducido automáticamente:

   TABLE PAR DEFAUT ([MiTabla])
   TOUT SELECTIONNER ([MiTabla])

Sin embargo, 4D también incluye una característica única, el comando EXECUTE FORMULA, el cual le permite construir código improvisadamente y luego ejecutarlo, aunque la base esté compilada.

El código de ejemplo, escrito con EXECUTE FORMULA en inglés, se verá así:

   EXECUTE FORMULA ( "DEFAULT TABLE([MiTabla])")
   EXECUTE FORMULA ( "ALL RECORDS([MiTabla])")

El mismo código, abierto con la versión francesa de 4D, se traduce automáticamente:

   EXECUTER FORMULE ( "DEFAULT TABLE([MiTabla])")
   EXECUTER FORMULE ( "ALL RECORDS([MiTabla])")

4D traduce automáticamente EXECUTE FORMULA (inglés) a EXECUTER FORMULE (francés), pero no puede traducir las instrucciones pasadas al comando.

Si utiliza el comando EXECUTE FORMULA en su aplicación, puede utilizar Command name para eliminar los problemas de traducción asociados a este tipo de instrucciones, y así hacer instrucciones independientes del idioma. El código de ejemplo se convierte en:

   EXECUTE FORMULA (Command name (46)+"([MiTabla])")
   EXECUTE FORMULA (Command name (47)+"([MiTabla])")

Con una versión francesa de 4D, este código será:

   EXECUTER FORMULE (Nom commande (46)+"([MiTabla])")
   EXECUTER FORMULE (Nom commande (47)+"([MiTabla])")

Nota: Para conocer el número de un comando, consulte la sección Sintaxis de comando (por nombre).

Ejemplos

1. Para todas las tablas de su base de datos, usted tiene un formulario llamado "FORMULARIO DE ENTRADA" utilizado para la entrada de datos en cada tabla. Quiere añadir un método de proyecto genérico que va a designar este formulario como el formulario de entrada actual para la tabla cuyo puntero o nombre se pasó. Usted escribe:

      ` Método de proyecto FORMULARIO ENTRADA ESTANDAR
      ` FORMULARIO ENTRADA ESTANDAR ( Puntero {; Cadena })
      ` FORMULARIO ENTRADA ESTANDAR ( ->Tabla {; NomTabla })
   C_POINTER ($1)
   C_STRING (31;$2)

   If (Count parameters>=2)
      EXECUTE FORMULA (Command name (55)+"(["+$2+"];"FORMULARIO ENTRADA")")
   Else
      If (Count parameters>=1)
         INPUT FORM ($1->;"FORMULARIO ENTRADA")
      End if
   End if

Una vez añadido este método de proyecto a su base, usted escribe:

FORMULARIO ENTRADA ESTANDAR  (->[Empleados])

FORMULARIO ENTRADA ESTANDAR  ("Empleados")

Nota: Generalmente, es preferible utilizar punteros cuando escribe rutinas genéricas. Primero, el código se ejecutará compilado si la base está compilada. Segundo, 4D Insider recuperará las referencias de los objetos cuyos punteros se pasaron. Tercero, como en el ejemplo anterior, su código dejará de funcionar correctamente si renombra la tabla. Sin embargo, en algunos casos, la utilización de EXECUTE FORMULA resolverá el problema.

2. En un formulario, usted quiere mostrar una lista desplegable que contenga los comandos estándar de generación de informes. En el método de objeto de esta lista desplegable, usted escribe:

   Case of
      : (Form event =On Before)
         ARRAY TEXT (asComando;4)
         asComando{1}:=Command name (1) ` Sum
         asComando{2}:=Command name (2) ` Average
         asComando{3}:=Command name (4) ` Min
         asComando{4}:=Command name (3) ` Max
      ` ...
   End case

En la versión inglesa de 4D, la lista desplegable contendrá: Sum, Average, Min, y Max. En la versión francesa, la lista desplegable contendrá: Somme, Moyenne, Min, y Max.

Ver también

EXECUTE FORMULA, Sintaxis de los comandos (por nombre).


4D - Documentation   Français   English   German   Español   English   4D v11 SQL, Comandos por temas   4D v11 SQL, Lista alfabética de comandos   4D v11 SQL, Constantes por temas   Regresar   Anterior   Siguiente